MetaTrader (MQL4 / MQL5) Development

input int FastPeriod = 10;   // Fast MA period
input int SlowPeriod = 50;   // Slow MA period

int      fastHandle, slowHandle;
datetime lastAlertBar = 0;

int OnInit()
{
   fastHandle = iMA(_Symbol, _Period, FastPeriod, 0, MODE_SMA, PRICE_CLOSE);
   slowHandle = iMA(_Symbol, _Period, SlowPeriod, 0, MODE_SMA, PRICE_CLOSE);
   return(INIT_SUCCEEDED);
}

int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
{
   if(rates_total < MathMax(FastPeriod, SlowPeriod) + 3)
      return(rates_total);

   double fast[2], slow[2];
   if(CopyBuffer(fastHandle, 0, 1, 2, fast) < 2) return(prev_calculated);
   if(CopyBuffer(slowHandle, 0, 1, 2, slow) < 2) return(prev_calculated);

   if(fast[0] <= slow[0] && fast[1] > slow[1])
   {
      datetime signalBar = time[rates_total - 1];
      if(signalBar != lastAlertBar)
      {
         lastAlertBar = signalBar;
         Alert(StringFormat("%s %s: MA(%d) crossed above MA(%d)",
                            _Symbol, EnumToString(_Period),
                            FastPeriod, SlowPeriod));
      }
   }

   return(rates_total);
}